!PLANE182: 4-nodes, 2D element, 2DOF/NODE (UX,UY)

!Steel, E=210E3, Poisson’s ratio 0.3

!Units are mm and N (therefore, E and stress are N/mm^2 = MPa)

FINISH !Finishes any previous activity

/CLEAR !Clears any previous activity

/BATCH !Works in “batch” mode

/PREP7

!Define geometry and load parameters.  
!Flat 100X30X10 plate with 20mm dia hole in middle

LENGTH=100

HEIGHT=30

THICKNESS=10

PRESSAREA=HEIGHT\*THICKNESS !The area that the applied load (“pressure” acts upon)

RADIUS=10  
APPLFORCE=10000

PRSR=-APPLFORCE/PRESSAREA

ET,1,PLANE182

MP,EX,1,210E3

MP,PRXY,1,0.3

KEYOPT,1,3,3 !Use plane stress (through the thickness)

R,1,THICKNESS !Use “THICKNESS” as the through thickness dimension

!Define locations of key points.

K,1,0,0,0

K,2,0,HEIGHT,0

K,3,LENGTH,HEIGHT,0

K,4,LENGTH,0,0

K,5,LENGTH/2,HEIGHT/2,0

L,1,2 !Create a line connecting Key Points 1 and 2.

L,2,3 !Line connect KP 2 and 3

L,3,4

L,4,1

CIRCLE,5,RADIUS

/PNUM,AREA,1

AL,ALL

SMRTSIZE,2

AMESH,ALL

FINISH

/SOLU

!Constrain in x directions the nodes at right edge:

NSEL,S,LOC,X,0 !select all nodes along X=0

D,ALL,ALL,0 !Prevents ALL displacement of selected nodes

!Apply force at right edge:  
!To apply a total force of LOAD, divide the LOAD by the area the pressure is acting on

NSEL,S,LOC,X,LENGTH

SF,ALL,PRES,PRSR

ALLSEL !Since we have used NSEL to select specific nodes, we now need ALLSEL to select all of the nodes

SOLVE

FINISH

/POST1

/ESHAPE,1 !Display element shapes using section data

/RGB,INDEX, 0, 0, 0,15 !set text color to black

/COLOR,WBAK,14 !Set background color to light grey

/DSCALE,ALL,1 !Plot using true scale

!/VIEW,1,1,1,1

FINISH !Finish and exit the post-processor

SAVE !Save the data base