!40x4x3 inch simply supported beam, 4000 pound load in middle

!PLANE182: 4-nodes, 2D element, 2DOF/NODE (UX,UY)

!Steel, E=29E6lb/in^2, Poisson’s ratio 0.3

FINISH !Finishes any previous activity

/CLEAR !Clears any previous activity

/BATCH !Works in “batch” mode

/PREP7

!Define Beam Geometry parameters. All dimensions are inches, all output will be in inches (or inch-squared)

LENGTH=40

HEIGHT=4

THICKNESS=3

LOAD=-4000

RECT,0,LENGTH,-HEIGHT/2,HEIGHT/2

ET,1,PLANE182

KEYOPT,1,3,3 !Use plane stress (through the thickness)

R,1,THICKNESS !Use “THICKNESS” as the through thickness dimension

MP,EX,1,29E6

MP,PRXY,1,0.3

ESIZE,.25 !element size, make smaller for more elements

AMESH,ALL !Mesh all areas

FINISH

/SOLU

!Constrain in both X and Y direction the nodes at bottom left edge:

NSEL,S,LOC,X,0 !select all nodes along X=0

NSEL,R,LOC,Y,-HEIGHT/2 !and at Y=HEIGHT/2

D,ALL,UY,0 !Prevents Y-displacement of selected nodes

D,ALL,UX,0 !Prevents X-displacement of selected nodes

!Constrain in Y-direction the nodes at bottom right edge:

NSEL,S,LOC,X,LENGTH

NSEL,R,LOC,Y,-HEIGHT/2

D,ALL,UY,0

!Apply force at top mid-span:

NSEL,S,LOC,X,LENGTH/2

NSEL,R,LOC,Y,HEIGHT/2

F,ALL,FY,-4000

ALLSEL !Since we have used NSEL to select specific nodes, we now need ALLSEL to select all of the nodes

SOLVE

FINISH

/POST1

/ESHAPE,1 !Display element shapes using section data

/RGB,INDEX, 0, 0, 0,15 !set text color to black

/COLOR,WBAK,14 !Set background color to light grey

/DSCALE,ALL,1 !Plot using true scale

/VIEW,1,1,1,1

FINISH !Finish and exit the post-processor

SAVE !Save the data base