!40x4x3 inch simply supported beam, 4000 pound load in middle

!SOLID185: 8-nodes, 3D element, 3DOF/NODE (UX,UY,UZ)

!Steel, E=29E6lb/in^2, Poisson’s ratio 0.3

FINISH !Finishes any previous activity

/CLEAR !Clears any previous activity

/BATCH !Works in “batch” mode

/PREP7

!Define Beam Geometry parameters.

!All dimensions are inches, all output will be in inches (or inch-squared)

LENGTH=40

HEIGHT=4

THICKNESS=3

LOAD=-4000

!BLOCK creates a block (3D volume) – this is the outline of the beam

!x length, y height, z thickness

BLOCK,0,LENGTH,-HEIGHT/2,HEIGHT/2,-THICKNESS/2,THICKNESS/2

ET,1,SOLID185

MP,EX,1,29E6

MP,PRXY,1,0.3

ESIZE,2 !Element size, needs changed for convergence study

VMESH,ALL

FINISH

/SOLU

!Select nodes to constrain on the left bottom of beam, constrain in X, Y, and Z

NSEL,S,LOC,X,0 !”S” = Select new set

NSEL,R,LOC,Y,-HEIGHT/2 !”R” = Reselect a set from the current set

D,ALL,UX,0

D,ALL,UY,0

D,ALL,UZ,0

!Select nodes on right bottom of beam, constrain in Y

NSEL,S,LOC,X,LENGTH

NSEL,R,LOC,Y,-HEIGHT/2

D,ALL,UY,0

!Select nodes and apply load at top mid-span front and back edges

NSEL,S,LOC,X,LENGTH/2

NSEL,R,LOC,Y,HEIGHT/2

NSEL,R,LOC,Z,THICKNESS/2

F,ALL,FY,LOAD/2 !force applied to front edge

NSEL,S,LOC,X,LENGTH/2

NSEL,R,LOC,Y,HEIGHT/2

NSEL,R,LOC,Z,-THICKNESS/2

F,ALL,FY,LOAD/2 !force applied to back edge

ALLSEL !Select all nodes to solve

SOLVE

FINISH

/POST1

!/GRAPHICS,OFF

/ESHAPE,1 !Display element shapes using section data

/RGB,INDEX, 0, 0, 0,15 !set text color to black

/COLOR,WBAK,14 !Set background color to light grey

/DSCALE,ALL,1 !Plot using true scale

/VIEW,1,1,1,1

FINISH !Finish and exit the post-processor

SAVE !Save the data base