!40x4x3 inch simply supported beam, 4000 pound load in middle

!BEAM188: 2-nodes, line body element, 6 DOF per NODE

!Steel, E=29E6lb/in^2, Poisson’s ratio 0.3

FINISH

/CLEAR

/PREP7

!Define Beam Geometry parameters. All dimensions are inches, all output will be in inches (or inch-squared)

LENGTH=40

HEIGHT=4

WIDTH=3

LOAD=-4000

!Define locations of key points.

K,1,0,0,0

K,2,LENGTH/2,0,0

K,3,LENGTH,0,0

L,1,2 !Create a line connecting Key Points 1 and 2.

L,2,3 !Line connect KP 2 and 3

!Define element information:

ET,1,BEAM188

SECTYPE,1,BEAM,RECT !Defines the cross-section of the beam as a rectangle.

SECOFFSET,CENT !This sets the beam node to be located at the beam’s cross-sectional centroid.

SECDATA,HEIGHT,WIDTH !we have defined HEIGHT and WIDTH

MP,EX,1,29e6 !MP = Material Property, EX is Modulus of elasticity

MP,PRXY,1,0.3 !PRXY is Poisson’s ratio

ESIZE,20 !Define element size

LSEL,ALL

LMESH,ALL !Mesh the line – in other words, create the elements

FINISH !Finish the preprocessing

/SOLU !Enter the solution processor (define loads and constraints)

DK,1,UX,0 !constrain x-displacement key point 1

DK,1,UY,0 !constrain y-displacement key point 1

DK,1,UZ,0 !constrain z-displacement key point 1

DK,1,ROTX,0 !constrain z-displacement key point 1

DK,1,ROTY,0 !constrain z-displacement key point 1

DK,3,UY,0 !constrain Y displacement at key point 3

!DK,3,UZ,0 !constrain z-displacement key point 3

FK,2,FY,LOAD !Apply force at key point 2 (midspan)

ALLSEL

SOLVE

FINISH !Finish and exit “solution”

/POST1 !Enter the general post-processor

/ESHAPE,1 !Display element shapes using section data

/DSCALE,ALL,1 !Plot using true scale

/RGB,INDEX, 0, 0, 0,15 !set text color to black

/COLOR,WBAK,14 !Set background color to light grey

/VIEW,1,1,1,1 !Isometric view

FINISH !Finish and exit the post-processor

SAVE !Save the data base