!Script by Kevin White, November 2019, ME304 Lecture

!Includes anisotropic “Layers”, load steps, paths, etc.

FINI

/CLEAR

!---DEFINE CONSTANTS FOR CLARITY AND EASE OF CODING

WIDE\_BODY=4.0E-2

NARROW\_BODY=2.5E-2

MID\_LENGTH=9E-2

FLT\_RAD=1.0E-2

TOT\_HGH=18.0E-2

TAB\_HGH=3.0E-2

RMP\_HGH=1.5E-2

RMP\_WTH=0.75E-2

THK=4E-3

LYR\_THK=0.5E-3

!---START PREPROCESSING AND USE ELEMENT TYPE SOLID186 LAYERED SOLID

/PREP7

ET,1,186,,,1

R,1

!---DEFINE THE MATERIAL PROPERTIES

MP,EX,1,172e9

MP,EY,1,10E9

MP,EZ,1,10E9

MP,GXY,1,5.5E9

MP,GXZ,1,3.2E9

MP,GYZ,1,3.2E9

MP,PRXY,1,0.27

MP,PRXZ,1,0.30

MP,PRYZ,1,0.30

!---DEFINE ORIENTATION AND SECTION DATA OF EACH LAYER

SECT,1,SHELL

SECD,LYR\_THK,1,0,3,LYRONE

SECD,LYR\_THK,1,30,3,LYRTWO

SECD,LYR\_THK,1,60,3,LYRTHREE

SECD,LYR\_THK,1,90,3,LYRFOUR

SECD,LYR\_THK,1,90,3,LYRFIVE

SECD,LYR\_THK,1,60,3,LYRSIX

SECD,LYR\_THK,1,30,3,LYRSEVEN

SECD,LYR\_THK,1,0,3,LYREIGHT

!---DEFINE KEYPOINT LOCATIONS

K,1,0,0,0

K,2,0,TAB\_HGH,0

K,3,RMP\_WTH,(TAB\_HGH+RMP\_HGH),0

K,4,RMP\_WTH,(TAB\_HGH+RMP\_HGH+MID\_LENGTH),0

K,5,0,(TOT\_HGH-TAB\_HGH),0

K,6,0,TOT\_HGH,0

K,7,WIDE\_BODY,TOT\_HGH,0

K,8,WIDE\_BODY,(TOT\_HGH-TAB\_HGH),0

K,9,(WIDE\_BODY-RMP\_WTH),(TOT\_HGH-TAB\_HGH-RMP\_HGH),0

K,10,(WIDE\_BODY-RMP\_WTH),(TAB\_HGH+RMP\_HGH),0

K,11,WIDE\_BODY,TAB\_HGH,0

K,12,WIDE\_BODY,0,0

!---CREATE LINES BETWEEN KEYPOINTS ESTABLISHING THE 2D DOGBONE SHAPE

L,1,2

L,2,3

L,3,4

L,4,5

L,5,6

L,6,7

L,7,8

L,8,9

L,9,10

L,10,11

L,11,12

L,12,1

!---CREATE FILLETS

LFILLT,1,2,FLT\_RAD

LFILLT,2,3,FLT\_RAD

LFILLT,3,4,FLT\_RAD

LFILLT,4,5,FLT\_RAD

LFILLT,7,8,FLT\_RAD

LFILLT,8,9,FLT\_RAD

LFILLT,9,10,FLT\_RAD

LFILLT,10,11,FLT\_RAD

!---CREATE AN AREA FROM THE CLOSED SHAPE OF LINES

AL,ALL

!---EXTRUDE A VOLUME FROM THE AREA

VEXT,1,,,,,THK

!---MESH THE VOLUME

TYPE,1

REAL,1

MAT,1

SECN,1

ESIZE,4E-3

VSWEEP,ALL

!---RESTRAIN ALL NODES AT THE BOTTOM FROM MOVEMENT IN ANY DIRECTION

NSEL,S,LOC,Y,0

D,ALL,ALL,0

ALLSEL

FINI

!---DEFINE THE SOLUTION TYPE AND START WITH NO LOAD AT TIME ZERO

/SOLU

ANTYPE,STATIC

OUTRES,ALL,ALL

TIME,1E-6

NSUBST,1

LSWRITE,1

!---MOVE THE TOP SURFACE OF THE DOG BONE UPWARDS 2MM OVER 60 SECONDS USING 10 SUB-STEPS

NSEL,S,LOC,Y,TOT\_HGH

D,ALL,UY,2E-3

ALLSEL

KBC,0

TIME,60

NSUBST,10

LSWRITE,2

LSSOLVE,1,2,1

FINI

!---ENTER POST-PROCESSING AND PRINT ELEMENT SOLUTIONS FOR STRESS

!---AND ELASTIC STRAIN IN THE Y DIRECTION

/POST1

SET,LAST

PLESOL,S,Y

PLESOL,EPEL,Y

!---DEFINE A PATH STRAIGHT UP THE MIDDLE OF THE DOG BONE AND DISPLAY ON A GRAPH

!---THE ELEMENT STRESS AND ELASTIC STRAIN IN THE Y DIRECTION

PATH,VPATH,2,30,100

PPATH,1,,2E-2,0,2E-3

PPATH,2,,2E-2,TOT\_HGH,2E-3

PDEF,VSY,S,Y,AVG

PDEF,VEY,EPEL,Y,AVG

PLPATH,VEY

PLPATH,VSY

FINI