!Quick notes for using ANSYS APDL

!All text following exclamation points (!) are ignored (comments)

!Open ANSYS APDL (search for APDL)

!Cut and paste all of this script into the “command line” in APDL

!Helpful links are posted in the ME328 hw table

!PLANE182: 4-nodes, 2D element, 2DOF/NODE (UX,UY)

!Aluminum, E=10E6, Poisson’s ratio 0.33

!Units are in and pounds (therefore, E and stress are psi)

FINISH !Finishes any previous activity

/CLEAR !Clears any previous activity

/BATCH !Works in “batch” mode

/PREP7

!Define geometry and load parameters.
!Flat plate, 1X1X10, with half-symmetry: 1X1X5

!1-axis of symmetry – model 1/4 of whole

LENGTH=10/2

HEIGHT=1

THICKNESS=1

ET,1,PLANE182

MP,EX,1,10E6

MP,PRXY,1,0.33

KEYOPT,1,3,3 !Use plane stress (through the thickness)

R,1,THICKNESS !Use “THICKNESS” as the through thickness dimension

!Define locations of key points.

K,1,0,0,0

K,2,0,HEIGHT/2,0

K,3,0,HEIGHT,0

K,4,LENGTH,HEIGHT,0

K,5,LENGTH,0,0

L,1,2 !Create a line connecting Key Points 1 and 2.

L,2,3 !Line connect KP 2 and 3

L,3,4

L,4,5

L,5,1

/PNUM,AREA,1

AL,ALL

SMRTSIZE,3

AMESH,ALL

FINISH

/SOLU

!Apply symmetric constraints along right edge (center line of whole)

NSEL,S,LOC,X,LENGTH !select all nodes along X=LENGTH

D,ALL,UX,0 !Prevents ALL displacement of selected nodes

DK,2,UY,0

!Apply symmetric BC’s along bottom

!NSEL,S,LOC,Y,0

!D,ALL,UY,0

!Apply force at bottom left KP

FK,2,FX,-1

ALLSEL !Since we have used NSEL to select specific nodes, we now need ALLSEL to select all of the nodes

SOLVE

FINISH

/POST1

/ESHAPE,1 !Display element shapes using section data

/RGB,INDEX, 0, 0, 0,15 !set text color to black

/COLOR,WBAK,14 !Set background color to light grey

/DSCALE,ALL,1 !Plot using true scale

!/VIEW,1,1,1,1

FINISH !Finish and exit the post-processor

SAVE !Save the data base