reset
#
set terminal pslatex color rotate auxfile size 2.50,1.80 8
#
# Data sources
MountPoint = '~/SSHFS/'
Folder = 'Helmholtz/Results/'
#
DataFile='Moduli_K.txt'
#
unset key
#set grid back
#
# Line styles of plotting DEM results
set style line 1 dt 1 lw 2.0 lc rgb "#8B0000" # dark red       Spheres
set style line 2 dt 12 lw 2.5 lc rgb "#191970" # midnight blue  Ovoids_0800
set style line 3 dt 3 lw 2.0 lc rgb "#006400" # dark green     Ovoids_0625
set style line 4 dt 4 lw 2.0 lc rgb "black"   #                Ovoids_0500
#
set style line 5 dt 5 lw 2.5 lc rgb "purple"
set style line 6 dt 1 lw 3 lc rgb "blue"
set style line 7 dt 5 lw 2.0 lc rgb "orangered4"
#
# black lines
set style line 8 dt 2  lw 1 lc rgb "black"    # Thin black lines
set style line 9 dt 3  lw 1.5 lc rgb "black"    # Zero axis  lines
set style line 10 dt 2 lw 1.4 lc rgb "black"    # Zero axis  lines
set style line 11 dt 6 lw 2.0 lc rgb "#191970"
set style line 12 dt 1 lw 1.4 lc rgb "green"
#
# Experimental (Tsukamoto) lines
set style line 20 dt 3 lw 1.0 lc rgb "black"
set style line 21 dt 3 lw 1.4 lc rgb "green"
set style line 22 dt 1 lw 1.0 lc rgb "black"
set style line 23 dt 1 lw 1.0 lc rgb "black"
set style line 24 dt 2 lw 0.5 lc rgb "black"
set style line 25 dt 1 lw 2.0 lc rgb "#8B0000" # dark red       Spheres
set style line 26 dt 2 lw 2.5 lc rgb "#191970" # midnight blue  Ovoids_0800
#
set border lw 3.0
#
set xlabel 'Strain, $-\varepsilon_{11}$, percent' offset 0,0.3
set ylabel '\parbox{1.60in}{\centering Contact density, $M^{\prime}/V$,\\[0.5ex] $10^{12}\:\text{m}^{-3}$}' offset -1.5,0
set y2label 'Fabric anisotropy, $\zeta$' offset -0.5,0
#
set xrange[0:11];  set xtics offset 0,0 2 5; set mxtics 5; #set format x ""
set yrange[0:2]; set ytics nomirror offset 0.3,0 1; set mytics 2; #set format y "%.1f"
set y2range[0:0.16]; set y2tics offset -0.3,0 0.05; set my2tics 5; set format y2 "%.2f"
#
#set label '{\footnotesize Contact density}' at 4.50,1.5
#set label '{\footnotesize Anisotropy}' at 4.50,0.7
#
set key at 1.5,0.60 left top Left reverse samplen 3.0 spacing 1.20 noautotitles nobox
#
plot MountPoint.Folder.DataFile using (100*$1):($7/$8/1e12) \
                                axes x1y1 \
                                with points pt 7 ps 0.45 lc rgb "black", \
     MountPoint.Folder.DataFile using (100*$1):(1*$9) \
                                axes x1y2 \
                                with points pt 6 ps 0.45 lc rgb "black", \
     MountPoint.Folder.DataFile using (100*$1):($7/$8/1e12) \
                                smooth bezier axes x1y1 \
                                title '\scriptsize{Contact density}' \
                                with lines ls 25, \
     MountPoint.Folder.DataFile using (100*$1):(1*$9) \
                                smooth bezier axes x1y2 \
                                title '\scriptsize{Fabric anisotropy}' \
                                with lines ls 26
